4c25123d83
Summary: This puts the whole installation and packaging under a single point of entry. (Docker, DEB, RPM, etc.) Rename alpha.dockerfile to beta.dockerfile Use Debian Stretch for docker Remove building old hardcoded compiler Rename build_interpreter to build_memgraph Remove unused config-file Reviewers: mferencevic, buda Reviewed By: mferencevic, buda Subscribers: pullbot Differential Revision: https://phabricator.memgraph.io/D857
43 lines
1.7 KiB
CMake
43 lines
1.7 KiB
CMake
# set current directory name as a test type
|
|
get_filename_component(test_type ${CMAKE_CURRENT_SOURCE_DIR} NAME)
|
|
|
|
# get all cpp abs file names recursively starting from current directory
|
|
file(GLOB_RECURSE test_type_cpps *.cpp)
|
|
message(STATUS "Available ${test_type} cpp files are: ${test_type_cpps}")
|
|
|
|
# for each cpp file build binary and register test
|
|
foreach(test_cpp ${test_type_cpps})
|
|
|
|
# get exec name (remove extension from the abs path)
|
|
get_filename_component(exec_name ${test_cpp} NAME_WE)
|
|
|
|
set(target_name memgraph__${test_type}__${exec_name})
|
|
|
|
# build exec file
|
|
add_executable(${target_name} ${test_cpp})
|
|
set_property(TARGET ${target_name} PROPERTY CXX_STANDARD ${cxx_standard})
|
|
if(TEST_COVERAGE)
|
|
set_target_properties(${target_name} PROPERTIES COMPILE_FLAGS "-g -O0 -Wall -fprofile-arcs -ftest-coverage")
|
|
set_target_properties(${target_name} PROPERTIES LINK_FLAGS "--coverage -fprofile-arcs -ftest-coverage")
|
|
endif()
|
|
|
|
# OUTPUT_NAME sets the real name of a target when it is built and can be
|
|
# used to help create two targets of the same name even though CMake
|
|
# requires unique logical target names
|
|
set_target_properties(${target_name} PROPERTIES OUTPUT_NAME ${exec_name})
|
|
|
|
# link libraries
|
|
target_link_libraries(${target_name} memgraph_lib)
|
|
# gtest
|
|
target_link_libraries(${target_name} gtest gmock gtest_main)
|
|
if(TEST_COVERAGE)
|
|
# for code coverage
|
|
target_link_libraries(${target_name} gcov)
|
|
endif()
|
|
|
|
# register test
|
|
set(output_path ${CMAKE_BINARY_DIR}/test_results/unit/${target_name}.xml)
|
|
add_test(${target_name} ${exec_name} --gtest_output=xml:${output_path})
|
|
|
|
endforeach()
|