mirror of
https://github.com/google/benchmark.git
synced 2025-03-22 23:20:29 +08:00
7b03df7ff7
* Add tests to verify assembler output -- Fix DoNotOptimize. For things like `DoNotOptimize`, `ClobberMemory`, and even `KeepRunning()`, it is important exactly what assembly they generate. However, we currently have no way to test this. Instead it must be manually validated every time a change occurs -- including a change in compiler version. This patch attempts to introduce a way to test the assembled output automatically. It's mirrors how LLVM verifies compiler output, and it uses LLVM FileCheck to run the tests in a similar way. The tests function by generating the assembly for a test in CMake, and then using FileCheck to verify the // CHECK lines in the source file are found in the generated assembly. Currently, the tests only run on 64-bit x86 systems under GCC and Clang, and when FileCheck is found on the system. Additionally, this patch tries to improve the code gen from DoNotOptimize. This should probably be a separate change, but I needed something to test. * Disable assembly tests on Bazel for now * Link FIXME to github issue * Fix Tests on OS X * fix strip_asm.py to work on both Linux and OS X like targets
46 lines
1.4 KiB
CMake
46 lines
1.4 KiB
CMake
|
|
|
|
set(ASM_TEST_FLAGS "")
|
|
check_cxx_compiler_flag(-O3 BENCHMARK_HAS_O3_FLAG)
|
|
if (BENCHMARK_HAS_O3_FLAG)
|
|
list(APPEND ASM_TEST_FLAGS -O3)
|
|
endif()
|
|
|
|
check_cxx_compiler_flag(-g0 BENCHMARK_HAS_G0_FLAG)
|
|
if (BENCHMARK_HAS_G0_FLAG)
|
|
list(APPEND ASM_TEST_FLAGS -g0)
|
|
endif()
|
|
|
|
check_cxx_compiler_flag(-fno-stack-protector BENCHMARK_HAS_FNO_STACK_PROTECTOR_FLAG)
|
|
if (BENCHMARK_HAS_FNO_STACK_PROTECTOR_FLAG)
|
|
list(APPEND ASM_TEST_FLAGS -fno-stack-protector)
|
|
endif()
|
|
|
|
split_list(ASM_TEST_FLAGS)
|
|
string(TOUPPER "${CMAKE_CXX_COMPILER_ID}" ASM_TEST_COMPILER)
|
|
|
|
macro(add_filecheck_test name)
|
|
cmake_parse_arguments(ARG "" "" "CHECK_PREFIXES" ${ARGV})
|
|
add_library(${name} OBJECT ${name}.cc)
|
|
set_target_properties(${name} PROPERTIES COMPILE_FLAGS "-S ${ASM_TEST_FLAGS}")
|
|
set(ASM_OUTPUT_FILE "${CMAKE_CURRENT_BINARY_DIR}/${name}.s")
|
|
add_custom_target(copy_${name} ALL
|
|
COMMAND ${PROJECT_SOURCE_DIR}/tools/strip_asm.py
|
|
$<TARGET_OBJECTS:${name}>
|
|
${ASM_OUTPUT_FILE}
|
|
BYPRODUCTS ${ASM_OUTPUT_FILE})
|
|
add_dependencies(copy_${name} ${name})
|
|
if (NOT ARG_CHECK_PREFIXES)
|
|
set(ARG_CHECK_PREFIXES "CHECK")
|
|
endif()
|
|
foreach(prefix ${ARG_CHECK_PREFIXES})
|
|
add_test(NAME run_${name}_${prefix}
|
|
COMMAND
|
|
${LLVM_FILECHECK_EXE} ${name}.cc
|
|
--input-file=${ASM_OUTPUT_FILE}
|
|
--check-prefixes=CHECK,CHECK-${ASM_TEST_COMPILER}
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
|
|
endforeach()
|
|
endmacro()
|
|
|